RESPUESTA A LA PREGUNTA 11073 - VISUAL BASIC


Lo que tienes que poner en el codigo dentro de la forma, es algo parecido a esto:

Dim strDisplayName As String
    Dim bStarted As Boolean
     
    strDisplayName = NTService1.DisplayName
     
    StatusBar.Panels(1).Text = "Cargado"
     
    If Command = "-install" Then
        ' enable interaction with desktop
        NTService1.Interactive = True
         
        If NTService1.Install Then
            Call NTService1.SaveSetting("Parameters", "TimerInterval", "1000")
            MsgBox strDisplayName & " installed successfully"
        Else
            MsgBox strDisplayName & " failed to install"
        End If
        End
    ElseIf Command = "-uninstall" Then
        If NTService1.Uninstall Then
            MsgBox strDisplayName & " uninstalled successfully"
        Else
            MsgBox strDisplayName & " failed to uninstall"
        End If
        End
    ElseIf Command = "-debug" Then
        NTService1.Debug = True
    ElseIf Command <> "" Then
        MsgBox "Invalid command option"
        End
    End If

y en la misma estructura del código tendras que colocar estas rutinas:

Private Sub NTService1_Continue(Success As Boolean)
On Error GoTo Err_Continue
     
    Success = True
    Call NTService1.LogEvent(svcEventInformation, svcMessageInfo, "Service continued")
     
    Exit Sub
    
Err_Continue:
    Call NTService1.LogEvent(svcMessageError, svcEventError, "[" & Err.Number & "] " & Err.Description)
End Sub

Private Sub NTService1_Pause(Success As Boolean)
On Error GoTo Err_Pause
     
    Timer.Enabled = False
    StatusBar.Panels(1).Text = "Paused"
    Call NTService1.LogEvent(svcEventError, svcMessageError, "Service paused")
    Success = True
     
    Exit Sub
    
Err_Pause:
    Call NTService1.LogEvent(svcMessageError, svcEventError, "[" & Err.Number & "] " & Err.Description)
End Sub

Private Sub NTService1_Start(Success As Boolean)
On Error GoTo Err_Start
     
    StatusBar.Panels(1).Text = "Running"
    Success = True
    
    Exit Sub
     
Err_Start:
    Call NTService1.LogEvent(svcMessageError, svcEventError, "[" & Err.Number & "] " & Err.Description)
End Sub


Private Sub NTService1_Stop()
On Error GoTo Err_Stop
     
    StatusBar.Panels(1).Text = "Stopped"
    Unload Me
     
    Exit Sub
    
Err_Stop:
    Call NTService1.LogEvent(svcMessageError, svcEventError, "[" & Err.Number & "] " & Err.Description)
End Sub



Arturo González E.
arthur98glz@yahoo.com

http://www.lawebdelprogramador.com