Visual Basic - Problema con bd en vb

Buenas tardes,

tengo un problemilla...estoy haciendo un programa en visual basic que contiene una base de datos access. Este programa tiene que funcionar tanto en mi ordenador como en el ordenador de los demás compañeros de faena, y claro, al tener la base de datos en una dirección de mi ordenador, cuando se ejecuta el programa en otro ordenador no encuentra la base de datos. Esta base de datos es una base de datos nueva en cada ordenador. Al crear el programa, que puedo hacer para que funcione en todos los ordenadores?

Gracias de antemano

hola joan...mmm yo diria que siempre pongas la base de datos dentro de la carpeta de tu sistema y la direccion de la base de datos lo configuras pues a esa carpeta.. y asi en los demas ordenadores la base es cuestion de q este en esa carpeta predeterminada..espero q me entiendas...

Si si que te entiendo, pero por ejemplo, si en mi ordenador tengo el disco duro en la C:\ y en el de mi compañero es l:\ no funcionará... No hay ninguna forma para crear la base de datos la primera vez que abres el programa o algo parecido?

avgbrmdz gracias por contestarme, si no hay otra forma lo haré de esta manera que me has dicho tu ;)

Saludos

mira joan te dare un ejemplo de como digo yo que tienes q hacerlo..
cn.CursorLocation = adUseClient
db = App.Path + "/practi.mdb" ' ruta dela bd
cn.Open "Provider=Microsoft.Jet.Oledb.4.0;Data Source=" & db

previamente declaras cn como conexion y db como cadena de conexion...
y si por ejemplo...quieres establecer antes de empezar a utilizar el sistema usa una variable de cadena que la obtienes de un text talvez y la pones
db=' tu variable de la base de datos'

espero que te sirva de algo todo esto...

Ostia, perfecto. Muchas gracias :)

Voy a probarlo :P

Saludos :)

Instalar la base de datos nueva cuando se instala el programa con el instalador en app path y usar app.path al nombrar la base de datos en tu aplicación.
Si no, para crear una bd access en código usar esto:

Sub Crear_Base_Dato(path As String, Tabla As String)

' path= nombre completo de la base datos a crear, incluido el path
' tabla= nombre de la tabla a crear
'Sub para crear la bd mediante Adox _
'Nota: Especificar la referencia a Microsoft Ado Ext. 2.x for DDL and Security

On Error GoTo ErrSub
'
Dim Adox_Cat As ADOX.Catalog
Dim Adox_Tabla As ADOX.Table

' La rutina no comprueba si la base de datos ya existe _
por lo tanto verificar previamente para que no de error

' Nuevo objeto de tipo catalog
Set Adox_Cat = New ADOX.Catalog

'Crea la base de datos en el path especificado
Adox_Cat.Create "Provider=Microsoft.Jet.OLEDB.4.0;" & "Data Source=" & path & ";"

' Nuevo objeto de tipo Table de ADOX para manejar la tabla
Set Adox_Tabla = New ADOX.Table
Adox_Tabla.Name = Tabla

'Agrega 3 campos, dos de tipo String y uno de tipo entero
Adox_Tabla.Columns.Append "Nombre", adVarWChar, 40
Adox_Tabla.Columns.Append "Apellido", adVarWChar, 40
Adox_Tabla.Columns.Append "Edad", adInteger

' Crea la tabla
Adox_Cat.Tables.Append Adox_Tabla

Set Adox_Tabla = Nothing
Set Adox_Cat = Nothing

Exit Sub

'Error
ErrSub:

MsgBox Err.Description, vbCritical

End Sub