Ensamblador - Imprimir variable con interrupción 10h

HexWrite8 proc

;

; AL has two hex digits that will be written to ES:EDI in ASCII form

;

        mov     ah, al

        and     al, 0fh

        shr     ah, 4

                                ; ah has MSD

                                ; al has LSD

        or      ax, 3030h

        xchg    al, ah

        cmp     ah, 39h

        ja      @@4

@@1:

        cmp     al, 39h

        ja      @@3

@@2:

        stosw

        ret

@@3:

        sub     al, 30h

        add     al, 'A' - 10

        jmp     @@2

@@4:

        sub     ah, 30h

        add     ah, 'A' - 10

        jmp     @@1

HexWrite8 endp

;-----------------------------------------------------------------------------

HexWrite16 proc

;

; AX has four hex digits in it that will be written to ES:EDI

;

        push    ax

        xchg    al,ah

        call    HexWrite8

        pop     ax

        call    HexWrite8

        ret

HexWrite16 endp

;-----------------------------------------------------------------------------

HexWrite32 proc

;

; EAX has eight hex digits in it that will be written to ES:EDI

;

        push    eax

        shr     eax, 16

        call    HexWrite16

        pop     eax

        call    HexWrite16

        ret

HexWrite32 endp

;-----------------------------------------------------------------------------