Visual Basic - correo en visual

hola estoy intentando una programacion en visual basic que consiste en tener un campo de txto con una direccion de correo electronico y quiero que cuando aprete un boton se me abra el micrsoft office outlook , preparado ya para mandar un correo a la direccion que ponia en el campo de txto
he visto por ahi codigo pero no consigo que ninguno funcione, incluso he encontrado en algun sitio una programacion que cuando le pongo en inicio ejecutar
MailTo:[email protected]?Subject=, me abre el correo , para mandar un mensaje a la direccion pablomoscardo@copitival y vacio en el asunto y objeto
a ver si alguien me puede echar una mano con esto
gracias
soy novato
saludos

Esto en el General del Formulario

Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hWnd As Long, _
ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory _
As String, ByVal nShowCmd As Long) As Long
Private Const SW_SHOWNORMAL = 1

Y esto en el Boton

Private Sub Command1_Click()
'Para CCs (con copia): &CC= (seguido de la lista)
'Para copia invisble: &BCC= (seguido de la lista)
'Para el asunto: &Subject= (seguido del texto)
'Para el cuerpo del mensaje: &Body= (seguido del texto)
'Para fichero anexados: &Attach= (seguido de un nombre de fichero válido entre comillas chr(34))
Dim sText As String
Dim sAddedText As String
If Len(txtMainAddresses) Then
sText = txtMainAddresses
End If
If Len(txtCC) Then
sAddedText = sAddedText & "&CC=" & txtCC
End If
If Len(txtBCC) Then
sAddedText = sAddedText & "&BCC=" & txtBCC
End If
If Len(txtSubject) Then
sAddedText = sAddedText & "&Subject=" & txtSubject
End If
If Len(txtBody) Then
sAddedText = sAddedText & "&Body=" & txtBody
End If
If Len(txtAttachmentFileLocation) Then
sAddedText = sAddedText & "&Attach=" & Chr(34) & txtAttachmentFileLocation & Chr(34)
End If
sText = "mailto:" & sText
' clean the added elements
If Len(sAddedText) <> 0 Then
' there are added elements, replace the first
' ampersand with the question character
Mid$(sAddedText, 1, 1) = "?"
End If
sText = sText & sAddedText
If Len(sText) Then
Call ShellExecute(Me.hWnd, "open", sText, vbNullString, vbNullString, SW_SHOWNORMAL)
End If
End Sub

Este código lo conseguí en este foro, tiene que estar por ahí, lo adapté a mis necesidades y funciona.